iox-2343 Add Findacl.cmake to setup libacl dependency

doc/website/release-notes/iceoryx-unreleased.md

@@ -76,6 +76,7 @@
 - Make iceoryx resource prefix a compile time option [#2272](https://github.com/eclipse-iceoryx/iceoryx/issues/2272)
 - Improve introspection-client interface by adding the number of ports in parentheses [#2299](https://github.com/eclipse-iceoryx/iceoryx/issues/2299)
 - Add std::atomic abstraction [#2329](https://github.com/eclipse-iceoryx/iceoryx/issues/2329)
+- Add Findacl.cmake module for ACL library detection [#2343](https://github.com/eclipse-iceoryx/iceoryx/issues/2343)
 - Port iceoryx to bzlmod [#2325](https://github.com/eclipse-iceoryx/iceoryx/issues/2325)
 - Make ACL support optional [#1176](https://github.com/eclipse-iceoryx/iceoryx/issues/1176)
 - Implement subscriber/publisher options in introspection [#2076](https://github.com/eclipse-iceoryx/iceoryx/issues/2076)

iceoryx_platform/CMakeLists.txt

@@ -60,6 +60,7 @@ else()
 endif()
 
 set(PREFIX iceoryx/v${CMAKE_PROJECT_VERSION})
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
 include("${CMAKE_CURRENT_LIST_DIR}/cmake/IceoryxConfigureOptionMacro.cmake")
 include("${CMAKE_CURRENT_LIST_DIR}/cmake/iceoryxversions.cmake")
 
@@ -83,7 +84,8 @@ file ( GLOB_RECURSE ICEORYX_PLATFORM_FILES
 
 if(IOX_PLATFORM_FEATURE_ACL)
     set(IOX_CFG_FEATURE_ACL "1")
-    set(ACL_LIB acl)
+    find_package(acl REQUIRED)
+    set(ACL_LIB acl::libacl)
 else()
     set(IOX_CFG_FEATURE_ACL "0")
     set(ACL_LIB)

iceoryx_platform/cmake/Findacl.cmake

@@ -0,0 +1,72 @@
+# Copyright (c) 2026 by Functionhx <2994114386@qq.com>. All rights reserved.
+#
+# This program and the accompanying materials are made available under the
+# terms of the Apache Software License 2.0 which is available at
+# https://www.apache.org/licenses/LICENSE-2.0, or the MIT license
+# which is available at https://opensource.org/licenses/MIT.
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+# SPDX-License-Identifier: Apache-2.0 OR MIT
+
+#[=======================================================================[.rst:
+Findacl
+-------
+
+Finds the ACL (Access Control Lists) library.
+
+Imported Targets
+^^^^^^^^^^^^^^^^
+
+This module provides the following imported target, if found:
+
+``acl::libacl``
+  The ACL library
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+``acl_FOUND``
+  True if the ACL library was found
+``acl_INCLUDE_DIRS``
+  Include directories for ACL headers
+``acl_LIBRARIES``
+  Libraries to link against
+
+#]=======================================================================]
+
+find_path(
+  acl_INCLUDE_DIR
+  NAMES sys/acl.h
+  DOC "ACL include directory"
+)
+
+find_library(
+  acl_LIBRARY
+  NAMES acl
+  DOC "ACL library"
+)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(acl
+  REQUIRED_VARS acl_LIBRARY acl_INCLUDE_DIR
+)
+
+set(acl_INCLUDE_DIRS "${acl_INCLUDE_DIR}")
+set(acl_LIBRARIES "${acl_LIBRARY}")
+
+if(acl_FOUND AND NOT TARGET acl::libacl)
+  add_library(acl::libacl UNKNOWN IMPORTED)
+  set_target_properties(acl::libacl PROPERTIES
+    IMPORTED_LOCATION "${acl_LIBRARY}"
+    INTERFACE_INCLUDE_DIRECTORIES "${acl_INCLUDE_DIR}"
+  )
+endif()
+
+mark_as_advanced(acl_INCLUDE_DIR acl_LIBRARY)